Schedule Flows Using Power Automate for Desktop

Did you know that the free edition of Power Automate Desktop does not include flow scheduling? Use this template to schedule flows.

SET DelayInMinutes TO 1
Variables.CreateNewList List=> TriggerDateTimeList
DISABLE Variables.AddItemToList Item: $'''08:10''' List: TriggerDateTimeList
DISABLE Variables.AddItemToList Item: $'''Sunday 11:15''' List: TriggerDateTimeList
DateTime.GetCurrentDateTime.Local DateTimeFormat: DateTime.DateTimeFormat.DateAndTime CurrentDateTime=> PreviousDateTime
LOOP LoopIndex FROM 1 TO 99999999 STEP 1
    DateTime.GetCurrentDateTime.Local DateTimeFormat: DateTime.DateTimeFormat.DateAndTime CurrentDateTime=> CurrentDateTime
    SET RunFlow TO $'''False'''
    IF IsNotEmpty(TriggerDateTimeList) THEN
        LOOP FOREACH TriggerDateTime IN TriggerDateTimeList
            Text.SplitText.Split Text: TriggerDateTime StandardDelimiter: Text.StandardDelimiter.Space DelimiterTimes: 1 Result=> DateTimeList
            IF DateTimeList.Count = 2 THEN
                Text.ConvertTextToDateTime.ToDateTime Text: $'''0001-01-01 %DateTimeList[1]%''' DateTime=> DateTimeObject
                IF (CurrentDateTime.DayOfWeek.ToLower = DateTimeList[0].ToLower AND CurrentDateTime.Hour = DateTimeObject.Hour AND CurrentDateTime.Minute = DateTimeObject.Minute) = $'''True''' THEN
                    SET RunFlow TO $'''True'''
                    EXIT LOOP
                END
            ELSE
                Text.ConvertTextToDateTime.ToDateTime Text: $'''0001-01-01 %DateTimeList[0]%''' DateTime=> DateTimeObject
                IF (CurrentDateTime.Hour = DateTimeObject.Hour AND CurrentDateTime.Minute = DateTimeObject.Minute) = $'''True''' THEN
                    SET RunFlow TO $'''True'''
                    EXIT LOOP
                END
            END
        END
    ELSE
        DateTime.Subtract FromDate: CurrentDateTime SubstractDate: PreviousDateTime TimeUnit: DateTime.DifferenceTimeUnit.Minutes TimeDifference=> TimeDifference
        IF (LoopIndex = 1 OR TimeDifference >= DelayInMinutes) = $'''True''' THEN
            SET RunFlow TO $'''True'''
        END
    END
    IF RunFlow = $'''True''' THEN
        SET PreviousDateTime TO CurrentDateTime
        # Trigger Your Flows Here
        DISABLE External.RunFlow FlowId: '00000000-0000-0000-0000-000000000000'
    END
    WAIT DelayInMinutes * 60
END
# Tested with Power Automate Desktop version 2.23.114.22217

SET DelayInMinutes TO 1
Variables.CreateNewList List=> TriggerDateTimeList
DISABLE Variables.AddItemToList Item: $'''08:10''' List: TriggerDateTimeList NewList=> TriggerDateTimeList
DISABLE Variables.AddItemToList Item: $'''Sunday 11:15''' List: TriggerDateTimeList NewList=> TriggerDateTimeList
DateTime.GetCurrentDateTime.Local DateTimeFormat: DateTime.DateTimeFormat.DateAndTime CurrentDateTime=> PreviousDateTime
LOOP LoopIndex FROM 1 TO 99999999 STEP 1
    DateTime.GetCurrentDateTime.Local DateTimeFormat: DateTime.DateTimeFormat.DateAndTime CurrentDateTime=> CurrentDateTime
    SET RunFlow TO $'''False'''
    IF IsNotEmpty(TriggerDateTimeList) THEN
        LOOP FOREACH TriggerDateTime IN TriggerDateTimeList
            Text.SplitText.Split Text: TriggerDateTime StandardDelimiter: Text.StandardDelimiter.Space DelimiterTimes: 1 Result=> DateTimeList
            IF DateTimeList.Count = 2 THEN
                Text.ConvertTextToDateTime.ToDateTime Text: $'''0001-01-01 %DateTimeList[1]%''' DateTime=> DateTimeObject
                IF (CurrentDateTime.DayOfWeek.ToLower = DateTimeList[0].ToLower AND CurrentDateTime.Hour = DateTimeObject.Hour AND CurrentDateTime.Minute = DateTimeObject.Minute) = $'''True''' THEN
                    SET RunFlow TO $'''True'''
                    EXIT LOOP
                END
            ELSE
                Text.ConvertTextToDateTime.ToDateTime Text: $'''0001-01-01 %DateTimeList[0]%''' DateTime=> DateTimeObject
                IF (CurrentDateTime.Hour = DateTimeObject.Hour AND CurrentDateTime.Minute = DateTimeObject.Minute) = $'''True''' THEN
                    SET RunFlow TO $'''True'''
                    EXIT LOOP
                END
            END
        END
    ELSE
        DateTime.Subtract FromDate: CurrentDateTime SubstractDate: PreviousDateTime TimeUnit: DateTime.DifferenceTimeUnit.Minutes TimeDifference=> TimeDifference
        IF (LoopIndex = 1 OR TimeDifference >= DelayInMinutes) = $'''True''' THEN
            SET RunFlow TO $'''True'''
        END
    END
    IF RunFlow = $'''True''' THEN
        SET PreviousDateTime TO CurrentDateTime
        # Trigger Your Flows Here
        DISABLE External.RunFlow FlowId: '00000000-0000-0000-0000-000000000000'
    END
    WAIT DelayInMinutes * 60
END
# Tested with Power Automate Desktop version 2.16.00306.22020

SET DelayInMinutes TO 1
Variables.CreateNewList List=> TriggerTimeList
DISABLE Variables.AddItemToList Item: $'''08:10''' List: TriggerTimeList NewList=> TriggerTimeList
DISABLE Variables.AddItemToList Item: $'''11:15''' List: TriggerTimeList NewList=> TriggerTimeList
DateTime.GetCurrentDateTime.Local DateTimeFormat: DateTime.DateTimeFormat.DateAndTime CurrentDateTime=> PreviousDateTime
LOOP LoopIndex FROM 1 TO 99999999 STEP 1
    DateTime.GetCurrentDateTime.Local DateTimeFormat: DateTime.DateTimeFormat.DateAndTime CurrentDateTime=> CurrentDateTime
    SET RunFlow TO $'''False'''
    IF IsNotEmpty(TriggerTimeList) THEN
        LOOP FOREACH TriggerTime IN TriggerTimeList
            Text.ConvertTextToDateTime.ToDateTime Text: $'''0001-01-01 %TriggerTime%''' DateTime=> TriggerTimeObject
            IF (CurrentDateTime.Hour = TriggerTimeObject.Hour AND CurrentDateTime.Minute = TriggerTimeObject.Minute) = $'''True''' THEN
                SET RunFlow TO $'''True'''
            END
        END
    ELSE
        DateTime.Subtract FromDate: CurrentDateTime SubstractDate: PreviousDateTime TimeUnit: DateTime.DifferenceTimeUnit.Minutes TimeDifference=> TimeDifference
        IF (LoopIndex = 1 OR TimeDifference >= DelayInMinutes) = $'''True''' THEN
            SET RunFlow TO $'''True'''
        END
    END
    IF RunFlow = $'''True''' THEN
        SET PreviousDateTime TO CurrentDateTime
        # Trigger Your Flows Here
        DISABLE External.RunFlow FlowId: '00000000-0000-0000-0000-000000000000'
    END
    WAIT DelayInMinutes * 60
END
# Tested with Power Automate Desktop version 2.15.284.21354

How It Works

Copy and paste the flow to Power Automate Desktop and set your scheduling triggers (see Instructions).

When creating a schedule trigger, you specify either a DelayInMinutes or DayOfWeek, and then choose your flow(s) that should be started. You can use multiple DayOfWeek triggers to kick off multiple flows.

Instructions

Version 1.4

Line 1: Set DelayInMinutes. Default is 1. This is the time in minutes the flow will wait until it will run again. Leave the value as-is if you plan to schedule the flow at specific times (see next row).
Line 3-4: (Optional) Enable these lines if you would like to schedule the flow to run daily at a specific day of week and time (e.g. Sunday 11:15). Use format DayOfWeek hh:mm or hh:mm (everyday). Use full day names: Monday, Tuesday, Wednesday, Thursday, Friday, Saturday, Sunday. Supports multiple time triggers (one line per trigger). If these lines are disabled then DelayInMinutes is used as a trigger instead.
Line 35: Choose which flows should be triggered (remember to enable this line). You could run multiple flows.

Notes

You need to manually restart this flow after logging in to Windows.
If you would like to purchase an attended or unattended license, you also need to set up a on-premises data gateway on the machine that will run PAD.

Changes

Version 1.4 - 2022-09-04

Updated flow actions to work with Power Automate Desktop version 2.23.114.22217.

Version 1.3 - 2022-02-06

Added support for day of week scheduling.

Version 1.2 - 2022-01-19

Added new feature: Trigger flows daily at specific times (supports multiple).

Version 1.1 - 2022-01-01

Updated flow actions to work with Power Automate Desktop version 2.15.284.21354.

Version 1.0 - 2021-10-11

First version, works only with Power Automate Desktop version 2.11.51.21196 and earlier.

References

[1]https://powerusers.microsoft.com/t5/Power-Automate-Ideas/Schedule-Power-Automate-Desktop-from-within-Windows-10/idi-p/847797

[2]https://powerusers.microsoft.com/t5/Power-Automate-Desktop/How-to-run-a-desktop-flow-from-windows-task-scheduler/td-p/844992

[3]https://www.reddit.com/r/MicrosoftFlow/comments/lwjjr3/scheduling_rpa_with_power_automate_desktop/

[4]https://stackoverflow.com/questions/70069653/is-there-a-way-to-schedule-and-run-a-power-automate-desktop-flow-from-desktop-it/70604382#70604382

Author

PAG Admin

Also See These Flows

Flow Action

Read Google Sheets API With Power Automate for Desktop

This example uses Invoke Web Service flow action to send a request to Google Sheets API, the response contains spreadsheet values.

PAG Admin

710

Flow Action

Visit Web Pages Found With Duckduckgo

Run DuckDuckGo in Chrome and visit first three links. Create a variable for CSS selectors to be able to click different links using an incremental loop counter.

PAG Admin

174

Flow Action

Find Text From Images Using Google Vision AI and OCR

This walkthrough shows all the steps it takes to analyze text from images with Optical Character Recognition (OCR) using Power Automate Desktop.

PAG Admin

407

Flow Action

PowerToys for Power Automate for Desktop

These PowerToy shortcuts are made for Windows users for the purpose of make their computing lives better.

PAG Admin

468

Flow Action

Run Flow From Command Prompt or Windows Task Scheduler

A simple way to run flows from Command Line, Windows Task Scheduler, shortcut keys or by using a URL.

PAG Admin

4,391