PowerToys for Power Automate for Desktop

These PowerToy shortcuts are made for Windows users for the purpose of make their computing lives better.

SET PowerToysPath TO $'''c:\\PowerAutomate'''
IF (Folder.IfFolderExists.DoesNotExist Path: PowerToysPath) THEN
    Display.ShowMessageDialog.ShowMessage Title: $'''Information''' Message: $'''Create missing directory?''' Icon: Display.Icon.Question Buttons: Display.Buttons.OKCancel DefaultButton: Display.DefaultButton.Button1 IsTopMost: True ButtonPressed=> ButtonPressed
    IF ButtonPressed = $'''OK''' THEN
        Folder.Create FolderPath: $'''%PowerToysPath[0]%:\\''' FolderName: PowerToysPath Folder=> NewFolder
    END
END
LABEL Restart
MouseAndKeyboard.WaitForShortcutKey.WaitForShortcutKey InputKeys: ['Ctrl+Shift+D1', 'Ctrl+Shift+D2', 'Ctrl+Shift+D3', 'Ctrl+Shift+D4', 'Ctrl+Shift+D5'] IndexOfShortcutKeyPressed=> IndexOfShortcutKeyPressed
IF IndexOfShortcutKeyPressed = 1 THEN
    # Show Clock With Seconds
    IF (File.IfFile.DoesNotExist File: $'''%PowerToysPath%\\PowerToys1.bat''') THEN
        SET RunClock TO $'''color 2a
title Time
mode con: cols=24 lines=2
:loop
@cls && @echo         %%time:~0,8%% && @timeout 1 > NUL
goto :loop'''
        File.WriteText File: $'''%PowerToysPath%\\PowerToys1.bat''' TextToWrite: RunClock AppendNewLine: True IfFileExists: File.IfFileExists.Overwrite Encoding: File.FileEncoding.DefaultEncoding
    END
    System.RunApplication.RunApplication ApplicationPath: $'''%PowerToysPath%\\PowerToys1.bat''' WindowStyle: System.ProcessWindowStyle.Normal ProcessId=> AppProcessId
ELSE IF IndexOfShortcutKeyPressed = 2 THEN
    # Open Two File Explorers Side By Side
    System.RunApplication.RunApplicationAndWaitToComplete ApplicationPath: $'''explorer''' WindowStyle: System.ProcessWindowStyle.Normal Timeout: 0 ExitCode=> AppExitCode
    System.RunApplication.RunApplicationAndWaitToComplete ApplicationPath: $'''explorer.exe''' WindowStyle: System.ProcessWindowStyle.Normal Timeout: 0 ExitCode=> AppExitCode
    WAIT 1
    MouseAndKeyboard.PressReleaseKey.PressKey Control: False Alt: False Shift: False Win: True
    MouseAndKeyboard.SendKeys.FocusAndSendKeys TextToSend: $'''{Left}{Return}''' DelayBetweenKeystrokes: 10 SendTextAsHardwareKeys: False
    MouseAndKeyboard.PressReleaseKey.ReleaseKey Control: False Alt: False Shift: False Win: True
    WAIT 1
    MouseAndKeyboard.SendKeys.FocusAndSendKeys TextToSend: $'''{Return}''' DelayBetweenKeystrokes: 10 SendTextAsHardwareKeys: False
ELSE IF IndexOfShortcutKeyPressed = 3 THEN
    # Extract Text From Screen
    OCR.ExtractTextWithOCR.ExtractTextFromScreenWithWindowsOcr WindowsOcrLanguage: OCR.WindowsOcrLanguage.English ImageWidthMultiplier: 1 ImageHeightMultiplier: 1 OcrText=> OcrText
    Clipboard.SetText Text: OcrText
    System.RunApplication.RunApplicationAndWaitToLoad ApplicationPath: $'''notepad.exe''' WindowStyle: System.ProcessWindowStyle.Normal Timeout: 0 ProcessId=> AppProcessId2 WindowHandle=> WindowHandle
    MouseAndKeyboard.SendKeys.FocusAndSendKeys TextToSend: $'''{Control}(V)''' DelayBetweenKeystrokes: 10 SendTextAsHardwareKeys: True
ELSE IF IndexOfShortcutKeyPressed = 4 THEN
    MouseAndKeyboard.WaitForShortcutKey.WaitForShortcutKey InputKeys: ['D1', 'D2', 'D3'] IndexOfShortcutKeyPressed=> IndexOfShortcutKeyPressed
    IF IndexOfShortcutKeyPressed = 1 THEN
        # Show System Info
        Scripting.RunDOSCommand.RunDOSCommand DOSCommandOrApplication: $'''SYSTEMINFO''' StandardOutput=> CommandOutput
        Display.ShowMessageDialog.ShowMessage Title: $'''Output''' Message: CommandOutput Icon: Display.Icon.None Buttons: Display.Buttons.OK DefaultButton: Display.DefaultButton.Button1 IsTopMost: False
    ELSE IF IndexOfShortcutKeyPressed = 2 THEN
        # Show IP Configuration
        Scripting.RunDOSCommand.RunDOSCommand DOSCommandOrApplication: $'''ipconfig /all''' StandardOutput=> CommandOutput
        Display.ShowMessageDialog.ShowMessage Title: $'''Output''' Message: CommandOutput Icon: Display.Icon.None Buttons: Display.Buttons.OK DefaultButton: Display.DefaultButton.Button1 IsTopMost: False
    ELSE IF IndexOfShortcutKeyPressed = 3 THEN
        # Show Wi-Fi Settings
        Scripting.RunDOSCommand.RunDOSCommand DOSCommandOrApplication: $'''netsh wlan show interfaces''' StandardOutput=> CommandOutput
        Display.ShowMessageDialog.ShowMessage Title: $'''Output''' Message: CommandOutput Icon: Display.Icon.None Buttons: Display.Buttons.OK DefaultButton: Display.DefaultButton.Button1 IsTopMost: False
    END
END
GOTO Restart
# Tested with Power Automate Desktop version 2.20.00133.22123

Features

Following PowerToys are included:

Show Clock With Seconds
Open Two File Explorers Side By Side
Extract Text From Screen
System Settings

Instructions

Line 1: Set a PowerToysPath value, default is c:\PowerAutomate. This is the path where .bat file will be saved to.
Run flow, then use shortcuts Ctrl+Shift+[number] to launch PowerToys.

Show Clock With Seconds

Shortcut: Ctrl+Shift+1

Background:
What is the number one, most annoying thing with Windows 11? It is…(drum roll, please)…the taskbar clock of course! Can you imagine, Windows taskbar does not show a clock that includes seconds! As a developer, this is really annoying since it is important to know how many seconds have elapsed after a specific task. There exists solutions like ElevenClock, but I don’t like to install third-party software for this kind of issue.

So, what is the solution? A PowerToys flow (of course) that will open a DOS prompt and show current time including seconds 👍!

Open Two File Explorers Side By Side

Shortcut: Ctrl+Shift+2

This PowerToy displays dual directory view panels that may serve as source and destination of a copy or move operation or just two different views of your files. Quick and easy.

Open two File Explorers side by side

Extract Text From Screen

Shortcut: Ctrl+Shift+3

This allows you to extract text from any screen/image and the output is shown in Notepad (no file saved).

Extract text from screen

System Settings - Show System Info

Shortcut: Ctrl+Shift+4 + 1

Want to know exact processor details, what brand of network card you have or the exact version of your Windows OS? This flow gets all the important information from your computer shown in a dialog box.

Show system info

System Settings - Show IP Configuration

Shortcut: Ctrl+Shift+4 + 2

Use this flow to quickly display all current TCP/IP network configuration values in a dialog box.

Show IP configuration

System Settings - Show Wi-Fi Settings

Shortcut: Ctrl+Shift+4 + 3

Use this flow to quickly display all current Wi-Fi interfaces and settings in a dialog box.

Show Wi-Fi settings

Notes

Shortcut key lists can’t include more than 5 shortcut keys. Therefore, all system settings have been stacked under a secondary shortcut key combination (eg. Ctrl+Shift+4 + [number])

Changes

Version 1.1 - 2022-05-29

Added new feature Show Wi-Fi Settings.
Remapped shortcuts since Wait For Shortcut Key only supports a maximum of 5 shortcuts.

Version 1.0 - 2022-05-22

PowerToys for PAD was created.

Author

PAG Admin

Also See These Flows

Flow Action

Find Text From Images Using Google Vision AI and OCR

This walkthrough shows all the steps it takes to analyze text from images with Optical Character Recognition (OCR) using Power Automate Desktop.

PAG Admin

504

Flow Action

Write to Google Sheets API Using OAuth 2.0 Power Automate for Desktop

Write cell values to spreadsheets. Includes basic logic for handling refresh tokens for repetitive tasks.

PAG Admin

1,980

Flow Action

PowerToys for Power Automate for Desktop

These PowerToy shortcuts are made for Windows users for the purpose of make their computing lives better.

PAG Admin

646

Flow Action

Schedule Flows Using Power Automate for Desktop

Did you know that the free edition of Power Automate Desktop does not include flow scheduling? Use this template to schedule flows.

PAG Admin

8,687

Flow Action

Basic Web Scraper Built With Power Automate for Desktop

A functional web scraper with complete flow actions. Showing how to scrape websites, traverse links and download content.

PAG Admin

2,762